請問指標訊號發出到下一個指標訊號之中的高點 要怎麼寫...

tibet8168

llem 發表於 14-11-20 03:21
努力翻書看了兩天還有有點不懂@@
這是指如果K20然後新的K>定義2的K =新的K值?  這邊K值是指KD指標的數字 ...

你要的是K or 價格? 都可以寫出來呀....................

llem

權限不夠無法傳訊@@

K值黃金交叉D(1)當時的價格 開始紀錄 到 下一次K值黃金交叉D(2)當時的價格 之中產生的價格高點(1到2的價格中的最高點)為(定義高點)(定義高點突破買入如無成交高點移動)
在下次的 K值黃金交叉D當時的價格 (3) 和 K值黃金交叉D當時的價格(2) 之間(2到3的高點)為新的價格高點定義 ... 之前的定義高點取消 改為最新的高點為定義高點  (定義高點突破買入)(定義高需一直移動直到成交)

麻煩你了  腦袋卡住=.=

easytrader788

input:Len(9),StopLoss(100);
vars: IsBalanceDay(False),MP(0),PF(0),PL(0),BuyCond(false),SellCond(false);

{ 部位狀況 }               
MP = MarketPosition ;

{ 結算日判斷 }
if DAYofMonth(Date) > 14 and DAYofMonth(Date) < 22 and DAYofWeek(Date)= 3 then isBalanceDay = True else isBalanceDay =False ;

{ KD 金叉 ,開始記錄高點( or 稱作 reset 高點) ,
買方條件成立 , 賣方條件不成立 }
if SlowK(Len) Cross over SlowD(Len) then Begin
        Value1 = High ;
        BuyCond = true ;
        SellCond = false ;
end ;

{ 若持續創高,記錄新高點 }
if High > Value1 then Value1 = High ;

{ 買方條件成立狀況下突破高點作多 }
if BuyCond then Buy next bar at Value1 stop ;

{ KD 死叉 ,開始記錄低點( or 稱作 reset 低點) ,
買方條件不成立 , 賣方條件成立 }
if SlowK(Len) Cross under SlowD(Len) then Begin
        Value2 = Low ;
        SellCond = true ;
        BuyCond = false ;
end;

{ 若持續破低,記錄新低點 }
if Low < Value2 then Value2 = Low ;

{ 賣方條件成立狀況下跌破低點作空 }
if SellCond then Sell next bar at Value2 stop ;

{ 部位變動 ,買賣方條件回歸 false ,準備重新記錄}
if MP <> MP[1] then Begin
BuyCond = false;
SellCond = false ;
end;

{ 設定停損點數 }
setstoploss(StopLoss*BigPointValue) ;

{ 結算日出場 }
if IsBalanceDay  then setExitonClose ;

llem

easytrader788 發表於 14-11-20 18:22
input:Len(9),StopLoss(100);
vars: IsBalanceDay(False),MP(0),PF(0),PL(0),BuyCond(false),SellCond(fals ...

大大 你簡直太體貼了 還有中文解釋>"<  這一定要好好吸收希望可以打通我的腦袋

fxj0008

學習了^^^^^^^^^^^^^^^^^