COCO研究院

 找回密碼
 註冊
搜索
COCO研究院»論壇 › 程式交易區 › AmiBroker討論區 › 如何能每日收市前強制平倉
返回列表 發新帖
查看: 3572|回復: 9

如何能每日收市前強制平倉

[複製鏈接]
Winson
發表於 13-7-23 16:40 | 顯示全部樓層 |閱讀模式
各位大大好 , 有個問題想請教
1.      現在有一張3個月的期貨1分鐘圖 , 我寫了程式做backtest , 我的策略是 daytrade , 不想過夜overnight , 但發覺常常overnight, 請問如何寫可以令在每日收市前強制平倉(close position)?
2.      在用buy / sell 的時候有沒有一個array variable 是儲起當時交易的bar number ? 因為buy = cross(ma1,ma2) 我好像只能在analysis result window 看到是那一個location 和buy price , 但在程次裡面有沒有這兩個資訊 ?
萬分感激!
回復

使用道具 舉報

Winson
 樓主| 發表於 13-7-23 18:05 | 顯示全部樓層
其實我是想問有沒有function 是拿時間的, 還是要重新的寫?
回復 支持 反對

使用道具 舉報

ys_chang
發表於 13-7-23 19:17 | 顯示全部樓層
Winson 發表於 13-7-23 18:05
其實我是想問有沒有function 是拿時間的, 還是要重新的寫?

CloseTime = 134400;
ExitTime = TimeNum() >= CloseTime;

Sell = ExitTime;
Cover = ExitTime;

回復 支持 反對

使用道具 舉報

merickelson
發表於 13-7-23 21:03 | 顯示全部樓層
為何捨近求遠？
一個保證在1344平倉的code供參：
var: CloseTime(1344) ;
condition1= Time>= CloseTime ;
if condition1 then begin
  Sell("-END")next bar at market;
  BuytoCover("end-")next bar at market;
end;
回復 支持 反對

使用道具 舉報

thirtycm
發表於 13-7-23 21:11 | 顯示全部樓層
merickelson 發表於 13-7-23 21:03
為何捨近求遠？
一個保證在1344平倉的code供參：
var: CloseTime(1344) ;

他是問amibroker的語法，不是multicharts的。
回復 支持 反對

使用道具 舉報

Winson
 樓主| 發表於 13-7-24 13:34 | 顯示全部樓層
感謝大家 ! 小弟用TimeNum() 可以處理了
==============================
OpenTime = 093000;   
CloseTime = 160000;   
ExitTime = TimeNum() >= CloseTime; //complusory Close position after 16:00
EntryTime = (TimeNum()>= OpenTime ) AND (TimeNum()<CloseTime);     //Entry only between 09:00 and 16:00
Buy=Cross( MA(C,10), MA(C,50) ) AND Month()==5 AND EntryTime;
Sell= (Cross( MA(C,50), MA(C,10) )AND Month()==5) OR ExitTime;
Short=Cross( MA(C,50), MA(C,10) )AND Month()==5 AND EntryTime;
Cover=(Cross( MA(C,10), MA(C,50) ) AND Month()==5) OR ExitTime;
=============================================
關於問題2 , 我找到一個叫 ValueWhen 的 function , 於是嘗試把它加進exploration window
abc=ValueWhen(Buy,C,1);
Filter=abc;
但它卻把所有buy 的"condition" 都加進去 , 而實際上因為我在setoption限制了合約張數 , 是不可能有那麼多進場點 , 想請教各位高手究竟buy / sell / short / cover 是不是array variable來的? 如果我用一些for loop 可否配合buy[i] 來找出回測時「買入的位置」與「買入價」 ? 這兩個數據對日後編寫出場條件十分重要 , 但我對buy/sell指令背後的概念卻很模糊 , 謝謝大家。
回復 支持 反對

使用道具 舉報

joshsmi
發表於 13-7-24 17:47 | 顯示全部樓層
本帖最後由 joshsmi 於 13-7-24 18:23 編輯

Stop writing "there is no function for this and there is no function for that" and "this seems to be impossible and that seems to impossible".

You can program everything! Learn how to code and look at the help file!

And since you are a total newbie here is a tip or one number one rule of programming:
Stop using the same expression or function over and over and over again (even more so if they are time consuming during processing). So put repeated calls to a variable! Otherwise you are limiting yourself.

// by joshsmi

OpenTime = 093000;
CloseTime = 160000;

tn = TimeNum();
mth = Month() == 7; // July only
MA1 = MA ( C, 10 );
MA2 = MA ( C, 50 );

CrossBuy = Cross ( MA1, MA2 );
CrossShort = Cross ( MA2, MA1 );

ExitTime = tn >= CloseTime; // compulsory Close position after 16:00
EntryTime = tn >= OpenTime AND tn < CloseTime; // Entry only between 09:00 AND 16:00

Buy = CrossBuy AND mth AND EntryTime;
Sell = CrossShort AND mth OR ExitTime;
Short = CrossShort AND mth AND EntryTime;
Cover = CrossBuy AND mth OR ExitTime;

BuyPrice = SellPrice = C;
ShortPrice = CoverPrice = C;


if ( Status( "action" ) == actionExplore )
{
// for exploration, not backtesting
    Filter = Buy || Short;

    AddColumn( IIf( Buy, BuyPrice, Null ), "BuyPrice", 1.4, colorLightYellow, colorDarkGreen );
    AddColumn( IIf( Short, ShortPrice, Null ), "ShortPrice", 1.4, colorLightYellow, colorDarkRed );
}


//for PLOT only :::::::::::::::::::::::::::::::::::::::::::::

if( Status( "action" ) == actionIndicator )
{
    // remove excessive signals
    Buy = ExRem( Buy, Sell );
    Sell = ExRem( Sell, Buy );
    Short = ExRem( Short, Cover );
    Cover = ExRem( Cover, Short );
   
    SetChartBkColor( colorBlack );
   
    SetChartOptions( 0, chartShowDates );
    SetBarFillColor( IIf( C > O, ColorRGB( 0, 75, 0 ), IIf( C <= O, ColorRGB( 75, 0, 0 ), colorLightGrey ) ) );
    Plot( C, "", IIf( C > O, ColorRGB( 0, 255, 0 ), IIf( C <= O, ColorRGB( 255, 0, 0 ), colorLightGrey ) ), 64, 0, 0, 0, 0 );

    Buycolor = colorGreen;
    Sellcolor  = colorOrange;
    Shortcolor = colorRed;
    Covercolor = colorLightBlue;
   
    PlotShapes( Buy*shapeSmallUpTriangle, Buycolor, 0, L, -15 );
    PlotShapes( Buy*shapeHollowSmallUpTriangle, colorLightGrey, 0, L, -15 );
    PlotShapes( Buy*shapeHollowSmallCircle, Buycolor, 0, BuyPrice, 0 );
   
    PlotShapes( Sell*shapeDownArrow, Sellcolor, 0, H, -15 );
    PlotShapes( Sell*shapeHollowDownArrow, colorLightGrey, 0, H, -15 );
    PlotShapes( Sell*shapeHollowSmallCircle, Sellcolor, 0, SellPrice, 0 );
   
    Shortdist = IIf( Short AND Sell, -30, -15 );
    PlotShapes( Short*shapeSmallDownTriangle, Shortcolor, 0, H, Shortdist );
    PlotShapes( Short*shapeHollowSmallDownTriangle, colorLightGrey, 0, H, Shortdist );
    PlotShapes( Short*shapeSmallCircle, Shortcolor, 0, ShortPrice, 0 );
   
    Coverdist = IIf( Cover AND Buy, -30, -15 );
    PlotShapes( Cover*shapeUpArrow, Covercolor, 0, L, Coverdist );
    PlotShapes( Cover*shapeHollowUpArrow, colorLightGrey, 0, L, Coverdist );
    PlotShapes( Cover*shapeSmallCircle, Covercolor, 0, CoverPrice, 0 );
   
    dist = 1.20 * ATR( 7 );
    pToggle = ParamToggle( "PlotText", "Disable|Enable", 1 );
    firstbar = Status( "firstvisiblebar" );
    lastbar = Min( BarCount, Status( "lastvisiblebar" ) );
   
    for ( i = firstbar; i < lastbar; i++ )
    {
        if( Short[ i ] AND Sell[ i ] )
             dist2[ i ] = 2 * dist[ i ];
        else dist2[ i ] = dist[ i ];
        
        if( Cover[ i ] AND Buy[ i ] )
             dist3[ i ] = 2 * dist[ i ];
        else dist3[ i ] = dist[ i ];
      
        if ( Buy[ i ] ) if ( pToggle )   PlotText( "Buy\n@" + BuyPrice[ i ], i, L[ i ] - dist[ i ], Buycolor );
        if ( Sell[ i ] ) if ( pToggle )  PlotText( "Sell\n@" + SellPrice[ i ], i, H[ i ] + dist[ i ], Sellcolor );
        if ( Short[ i ] ) if ( pToggle ) PlotText( "Short\n@" + ShortPrice[ i ], i, H[ i ] + dist2[ i ], Shortcolor );
        if ( Cover[ i ] ) if ( pToggle )  PlotText( "Cover\n@" + CoverPrice[ i ], i, L[ i ] - dist3[ i ], Covercolor );
    }
   
    _N(Title = StrFormat("{{NAME}} - {{INTERVAL}} {{DATE}} Open %g, Hi %g, Lo %g, Close %g (%.2f%%) {{VALUES}}", O, H, L, C, SelectedValue( ROC( C, 1 ) ) ));
   
    // stripes
    Colperiod  = ParamColor( "Color of periodic stripes", colorDarkGrey );
    Plot( EntryTime, "", Colperiod, styleArea | styleOwnScale | styleNoLabel, 0, 1, 0, -10 );
}

評分

參與人數 1金錢 +2 收起 理由
Winson + 2 joshsmi 大大的教誨, 我會緊記!

查看全部評分

回復 支持 反對

使用道具 舉報

joshsmi
發表於 13-7-24 17:52 | 顯示全部樓層
And another thing in "99% of cases" there is no loop needed.

回復 支持 反對

使用道具 舉報

joshsmi
發表於 13-7-24 17:57 | 顯示全部樓層
本帖最後由 joshsmi 於 13-7-24 18:27 編輯

above code seems to have some formatting errors so html paste doesn't seem work properly.

here is again using code tags to be sure
  1. // by joshsmi

  3. OpenTime = 093000;
  4. CloseTime = 160000;

  6. tn = TimeNum();
  7. mth = Month() == 7; // July only
  8. MA1 = MA ( C, 10 );
  9. MA2 = MA ( C, 50 );

  11. CrossBuy = Cross ( MA1, MA2 );
  12. CrossShort = Cross ( MA2, MA1 );

  14. ExitTime = tn >= CloseTime; // compulsory Close position after 16:00
  15. EntryTime = tn >= OpenTime AND tn < CloseTime; // Entry only between 09:00 AND 16:00

  17. Buy = CrossBuy AND mth AND EntryTime;
  18. Sell = CrossShort AND mth OR ExitTime;
  19. Short = CrossShort AND mth AND EntryTime;
  20. Cover = CrossBuy AND mth OR ExitTime;

  22. BuyPrice = SellPrice = C;
  23. ShortPrice = CoverPrice = C;


  26. if ( Status( "action" ) == actionExplore )
  27. {
  28. // for exploration, not backtesting
  29.     Filter = Buy || Short;

  31.     AddColumn( IIf( Buy, BuyPrice, Null ), "BuyPrice", 1.4, colorLightYellow, colorDarkGreen );
  32.     AddColumn( IIf( Short, ShortPrice, Null ), "ShortPrice", 1.4, colorLightYellow, colorDarkRed );
  33. }


  36. //for PLOT only :::::::::::::::::::::::::::::::::::::::::::::

  38. if( Status( "action" ) == actionIndicator )
  39. {
  40.     // remove excessive signals
  41.     Buy = ExRem( Buy, Sell );
  42.     Sell = ExRem( Sell, Buy );
  43.     Short = ExRem( Short, Cover );
  44.     Cover = ExRem( Cover, Short );
  45.    
  46.     SetChartBkColor( colorBlack );
  47.    
  48.     SetChartOptions( 0, chartShowDates );
  49.     SetBarFillColor( IIf( C > O, ColorRGB( 0, 75, 0 ), IIf( C <= O, ColorRGB( 75, 0, 0 ), colorLightGrey ) ) );
  50.     Plot( C, "", IIf( C > O, ColorRGB( 0, 255, 0 ), IIf( C <= O, ColorRGB( 255, 0, 0 ), colorLightGrey ) ), 64, 0, 0, 0, 0 );

  52.     Buycolor = colorGreen;
  53.     Sellcolor  = colorOrange;
  54.     Shortcolor = colorRed;
  55.     Covercolor = colorLightBlue;
  56.    
  57.     PlotShapes( Buy*shapeSmallUpTriangle, Buycolor, 0, L, -15 );
  58.     PlotShapes( Buy*shapeHollowSmallUpTriangle, colorLightGrey, 0, L, -15 );
  59.     PlotShapes( Buy*shapeHollowSmallCircle, Buycolor, 0, BuyPrice, 0 );
  60.    
  61.     PlotShapes( Sell*shapeDownArrow, Sellcolor, 0, H, -15 );
  62.     PlotShapes( Sell*shapeHollowDownArrow, colorLightGrey, 0, H, -15 );
  63.     PlotShapes( Sell*shapeHollowSmallCircle, Sellcolor, 0, SellPrice, 0 );
  64.    
  65.     Shortdist = IIf( Short AND Sell, -30, -15 );
  66.     PlotShapes( Short*shapeSmallDownTriangle, Shortcolor, 0, H, Shortdist );
  67.     PlotShapes( Short*shapeHollowSmallDownTriangle, colorLightGrey, 0, H, Shortdist );
  68.     PlotShapes( Short*shapeSmallCircle, Shortcolor, 0, ShortPrice, 0 );
  69.    
  70.     Coverdist = IIf( Cover AND Buy, -30, -15 );
  71.     PlotShapes( Cover*shapeUpArrow, Covercolor, 0, L, Coverdist );
  72.     PlotShapes( Cover*shapeHollowUpArrow, colorLightGrey, 0, L, Coverdist );
  73.     PlotShapes( Cover*shapeSmallCircle, Covercolor, 0, CoverPrice, 0 );
  74.    
  75.     dist = 1.20 * ATR( 7 );
  76.     pToggle = ParamToggle( "PlotText", "Disable|Enable", 1 );
  77.     firstbar = Status( "firstvisiblebar" );
  78.     lastbar = Min( BarCount, Status( "lastvisiblebar" ) );
  79.    
  80.     for ( i = firstbar; i < lastbar; i++ )
  81.     {
  82.         if( Short[ i ] AND Sell[ i ] )
  83.              dist2[ i ] = 2 * dist[ i ];
  84.         else dist2[ i ] = dist[ i ];
  85.         
  86.         if( Cover[ i ] AND Buy[ i ] )
  87.              dist3[ i ] = 2 * dist[ i ];
  88.         else dist3[ i ] = dist[ i ];
  89.       
  90.         if ( Buy[ i ] ) if ( pToggle )   PlotText( "Buy\n@" + BuyPrice[ i ], i, L[ i ] - dist[ i ], Buycolor );
  91.         if ( Sell[ i ] ) if ( pToggle )  PlotText( "Sell\n@" + SellPrice[ i ], i, H[ i ] + dist[ i ], Sellcolor );
  92.         if ( Short[ i ] ) if ( pToggle ) PlotText( "Short\n@" + ShortPrice[ i ], i, H[ i ] + dist2[ i ], Shortcolor );
  93.         if ( Cover[ i ] ) if ( pToggle )  PlotText( "Cover\n@" + CoverPrice[ i ], i, L[ i ] - dist3[ i ], Covercolor );
  94.     }
  95.    
  96.     _N(Title = StrFormat("{{NAME}} - {{INTERVAL}} {{DATE}} Open %g, Hi %g, Lo %g, Close %g (%.2f%%) {{VALUES}}", O, H, L, C, SelectedValue( ROC( C, 1 ) ) ));
  97.    
  98.     // stripes
  99.     Colperiod  = ParamColor( "Color of periodic stripes", colorDarkGrey );
  100.     Plot( EntryTime, "", Colperiod, styleArea | styleOwnScale | styleNoLabel, 0, 1, 0, -10 );
  101. }
複製代碼

評分

參與人數 1金錢 +2 收起 理由
Winson + 2 Joshsmi 大大真的很用心, 謝謝^^

查看全部評分

回復 支持 反對

使用道具 舉報

Winson
 樓主| 發表於 13-7-25 09:38 | 顯示全部樓層
Joshsmi 真的很用心, 小弟自中學後也沒有再編程, 和新手沒兩樣, 我會繼續努力 , 多謝指點^^
回復 支持 反對

使用道具 舉報

返回列表 發新帖
高級模式
B Color Image Link Quote Code Smilies
您需要登錄後才可以回帖 登錄 | 註冊

本版積分規則

手機版|Archiver|站長信箱|廣告洽詢|COCO研究院

GMT+8, 24-12-21 21:55

Powered by Discuz! X3.4

Copyright © 2001-2023, Tencent Cloud.

快速回復 返回頂部 返回列表
理財討論網站 |